File: backsort.awk
   1 #!/usr/bin/awk -f
   2 
   3 # The MIT License (MIT)
   4 #
   5 # Copyright © 2024 pacman64
   6 #
   7 # Permission is hereby granted, free of charge, to any person obtaining a copy
   8 # of this software and associated documentation files (the “Software”), to deal
   9 # in the Software without restriction, including without limitation the rights
  10 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  11 # copies of the Software, and to permit persons to whom the Software is
  12 # furnished to do so, subject to the following conditions:
  13 #
  14 # The above copyright notice and this permission notice shall be included in
  15 # all copies or substantial portions of the Software.
  16 #
  17 # THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  20 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  22 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  23 # SOFTWARE.
  24 
  25 
  26 # backsort [names/indices...]
  27 #
  28 # BACKward-SORT (numerically) using values from the column whose name matches
  29 # the argument given, either exactly, case-insensitively, as a 1-based index,
  30 # or even as a negative/backward index
  31 
  32 
  33 function findcol(name, lowname, i) {
  34     for (i = 1; i <= NF; i++) {
  35         if (name == $i) return i
  36     }
  37 
  38     for (i = 1; i <= NF; i++) {
  39         if (lowname == tolower($i)) return i
  40     }
  41 
  42     if (1 <= name && name <= NF) return name + 0
  43     if (name < 0 && -name <= NF) return NF + name + 1
  44 
  45     return 0
  46 }
  47 
  48 BEGIN {
  49     for (i = 1; i < ARGC; i++) {
  50         colnames[i] = ARGV[i]
  51         delete ARGV[i]
  52     }
  53 }
  54 
  55 { gsub(/\r$/, "") }
  56 
  57 NR == 1 {
  58     if ($0 ~ /\t/) FS = "\t"
  59 
  60     for (i = 1; i < ARGC; i++) lownames[i] = tolower(colnames[i])
  61 
  62     for (i = 1; i <= NF; i++) {
  63         j = findcol(colnames[i], lownames[i])
  64         if (j > 0) pos[++numcols] = j
  65     }
  66 
  67     cmd = "sort -t '\t'"
  68     for (i = 1; i <= numcols; i++) {
  69         cmd = cmd sprintf(" -rnk%d", pos[i])
  70     }
  71 
  72     print; fflush()
  73 }
  74 
  75 NR > 1 {
  76     if (numcols > 0) {
  77         print | cmd
  78     } else {
  79         print; fflush()
  80     }
  81 }