File: bsbs.sh
   1 #!/bin/sh
   2 
   3 # The MIT License (MIT)
   4 #
   5 # Copyright © 2024 pacman64
   6 #
   7 # Permission is hereby granted, free of charge, to any person obtaining a copy
   8 # of this software and associated documentation files (the “Software”), to deal
   9 # in the Software without restriction, including without limitation the rights
  10 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  11 # copies of the Software, and to permit persons to whom the Software is
  12 # furnished to do so, subject to the following conditions:
  13 #
  14 # The above copyright notice and this permission notice shall be included in
  15 # all copies or substantial portions of the Software.
  16 #
  17 # THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  20 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  22 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  23 # SOFTWARE.
  24 
  25 
  26 # bsbs [column count...] [filepaths...]
  27 #
  28 # Book-like Side-By-Side lays out lines read from all inputs given into several
  29 # columns, separating them with a special symbol. If no named inputs are given,
  30 # lines are read from the standard input, instead of files.
  31 #
  32 # If a column-count isn't given, it's 2 by default, just like with books.
  33 
  34 
  35 case "$1" in
  36     -h|--h|-help|--help)
  37         awk '/^# +bsbs/, /^$/ { gsub(/^# ?/, ""); print }' "$0"
  38         exit 0
  39     ;;
  40 esac
  41 
  42 num_columns=2
  43 if [ "$(echo "$1" | grep -E '^[+-]?[0-9]+$' 2> /dev/null)" ]; then
  44     num_columns="$1"
  45     shift
  46 fi
  47 
  48 if [ "${num_columns}" -lt 1 ]; then
  49     num_columns=1
  50 fi
  51 
  52 # use the current screen height minus 1
  53 height="$(($(tput lines) - 1))"
  54 
  55 if [ "${height}" -lt 1 ]; then
  56     printf "screen/window isn't tall enough to show content\n" > /dev/stderr
  57     exit 1
  58 fi
  59 
  60 awk '
  61     # ignore leading UTF-8 BOMs (byte-order marks)
  62     FNR == 1 { gsub(/^\xef\xbb\xbf/, "") }
  63 
  64     # carriage-returns will ruin side-by-side output, so remove them
  65     { gsub(/\r$/, ""); print }
  66 ' "$@" |
  67 
  68 # before laying out lines side-by-side, expand all tabs, using 4 as the
  69 # tabstop width
  70 expand -t 4 |
  71 
  72 awk -v num_columns="${num_columns}" -v height="${height}" '
  73 BEGIN {
  74     sep = " █"
  75     sep_width = width(sep)
  76     height--
  77 }
  78 
  79 # remember all lines; carriage-returns are already removed
  80 { lines[NR - 1] = $0 }
  81 
  82 # width counts items in the string given, ignoring ANSI-style sequences
  83 function width(s) {
  84     gsub(/\x1b\[[0-9;]*[A-Za-z]/, "", s)
  85     return length(s)
  86 }
  87 
  88 # pick a line using a row-column pair as an index
  89 function pick(lines, height, page, row, col) {
  90     return lines[page + col * height + row]
  91 }
  92 
  93 # round up non-integers
  94 function ceil(n) {
  95     return (n % 1) ? n - (n % 1) + 1 : n
  96 }
  97 
  98 END {
  99     if (NR <= height) {
 100         for (i = 0; i < NR; i++) print lines[i]
 101         exit
 102     }
 103 
 104     # avoid empty trailing columns
 105     if (NR < height * num_columns) num_columns = ceil(NR / height)
 106     # ensure number of columns is valid
 107     if (num_columns < 1) num_columns = 1
 108 
 109     for (i = 0; i < NR; i += height * num_columns) {
 110         for (j = 0; j < height; j++) {
 111             for (k = 0; k < num_columns; k++) {
 112                 w = width(pick(lines, height, i, j, k))
 113                 if (max_widths[k] < w) max_widths[k] = w
 114             }
 115         }
 116     }
 117 
 118     widest = 0
 119     for (i in max_widths) {
 120         if (widest < max_widths[i]) widest = max_widths[i]
 121     }
 122 
 123     # make enough spaces to hand-pad lines later; these spaces can exceed
 124     # the max-count needed, since they are always subsliced when used later
 125     spaces = "                                "
 126     nspaces = length(spaces)
 127     while (nspaces < widest) {
 128         spaces = spaces spaces
 129         nspaces *= 2
 130     }
 131 
 132     total_max_width = 0
 133     for (i = 0; i < num_columns; i++) {
 134         if (i > 0) total_max_width += sep_width + 1
 135         total_max_width += max_widths[i]
 136     }
 137 
 138     # make a separator wide enough to match the length of any output line
 139     bottom_sep = "································"
 140     nsep = length(bottom_sep)
 141     while (nsep < total_max_width) {
 142         bottom_sep = bottom_sep bottom_sep
 143         nsep *= 2
 144     }
 145     # separator is used directly, so match the needed width exactly
 146     bottom_sep = substr(bottom_sep, 1, total_max_width)
 147 
 148     # emit lines side by side
 149     for (i = 0; i < NR; i += height * num_columns) {
 150         # emit a page-bottom/separator line between pages of columns
 151         if (i > 0) print bottom_sep
 152 
 153         for (j = 0; j < height; j++) {
 154             # bottom-pad last page-pair with empty lines, so page-scrolling
 155             # on viewers like `less` stays in sync with the page boundaries
 156             if (NR - i - j <= 0) {
 157                 print ""
 158                 continue
 159             }
 160 
 161             for (k = 0; k < num_columns; k++) {
 162                 l = pick(lines, height, i, j, k)
 163 
 164                 if (k > 0) {
 165                     printf "%s", sep
 166                     if (k != num_columns - 1 || l != "") printf " "
 167                 }
 168 
 169                 printf "%s", l
 170 
 171                 if (k < num_columns - 1) {
 172                     pad = max_widths[k] - width(l)
 173                     if (pad > 0) {
 174                         s = substr(spaces, 1, pad)
 175                         printf "%s", s
 176                     }
 177                 }
 178             }
 179 
 180             print ""
 181         }
 182     }
 183 
 184     # end last page with an empty line, instead of the usual page-separator
 185     if (NR > 0) print ""
 186 }
 187 ' | less -JMKiCRS