#!/usr/bin/awk -f

# The MIT License (MIT)
#
# Copyright © 2020-2025 pacman64
#
# Permission is hereby granted, free of charge, to any person obtaining a copy
# of this software and associated documentation files (the “Software”), to deal
# in the Software without restriction, including without limitation the rights
# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
# copies of the Software, and to permit persons to whom the Software is
# furnished to do so, subject to the following conditions:
#
# The above copyright notice and this permission notice shall be included in
# all copies or substantial portions of the Software.
#
# THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
# SOFTWARE.


# bully
# Tally input lines, also showing bullets for the tally count
#
#
# Show a reverse-sorted tally of all lines read, where ties are sorted
# alphabetically. In addition, a 3rd column with bullets helps you
# instinctively grasp tallies as quantities relative to each other.
#
# High tally counts will show a lot of bullets, of course, which isn't
# helpful: the regular tally script is better, in those cases.
#
# Output is a 3-item TSV table, which starts with a header line.


BEGIN { print "value\ttally\tbullets" }

{ tally[$0]++ }

END {
    # find the max tally, which is needed to build the bullets-string
    max = 0
    for (k in tally) {
        if (max < tally[k]) max = tally[k]
    }

    # make enough bullets for all tallies: this loop makes growing the
    # string a task with complexity O(n * log n), instead of a naive
    # O(n**2), which can slow-down things when tallies are high enough
    bullet = "•"
    bullets = bullet
    for (n = max; n > 1; n /= 2) {
        bullets = bullets bullets
    }

    # the sort cmd to use for the final output, along with its options
    sortcmd = "sort -t '\t' -rnk2 -k1d"

    # emit unsorted output lines to the sort cmd, which will emit the
    # final reverse-sorted tally lines
    for (k in tally) {
        t = tally[k]
        s = (t == 1) ? bullet : substr(bullets, 1, t)
        printf "%s\t%d\t%s\n", k, t, s | sortcmd
    }
}