File: cext.sh
   1 #!/bin/sh
   2 
   3 # The MIT License (MIT)
   4 #
   5 # Copyright © 2020-2025 pacman64
   6 #
   7 # Permission is hereby granted, free of charge, to any person obtaining a copy
   8 # of this software and associated documentation files (the “Software”), to deal
   9 # in the Software without restriction, including without limitation the rights
  10 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  11 # copies of the Software, and to permit persons to whom the Software is
  12 # furnished to do so, subject to the following conditions:
  13 #
  14 # The above copyright notice and this permission notice shall be included in
  15 # all copies or substantial portions of the Software.
  16 #
  17 # THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  20 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  22 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  23 # SOFTWARE.
  24 
  25 
  26 # cext [options...] [files...]
  27 #
  28 # Color/style file EXTensions makes all file-extensions stand out, using
  29 # different ANSI-styles as it finds new ones. Since its list of styles is
  30 # limited, these will start being reused, given enough unique extensions.
  31 #
  32 # The help option is `-h`, `--h`, `-help`, or `--help`.
  33 
  34 
  35 case "$1" in
  36     -h|--h|-help|--help)
  37         awk '/^# +cext /, /^$/ { gsub(/^# ?/, ""); print }' "$0"
  38         exit 0
  39     ;;
  40 esac
  41 
  42 awk '
  43 BEGIN {
  44     palette[n++] = "\x1b[38;2;0;95;215m" # blue
  45     palette[n++] = "\x1b[38;2;215;95;0m" # orange
  46     palette[n++] = "\x1b[38;2;135;95;255m" # purple
  47     palette[n++] = "\x1b[38;2;0;175;215m" # cyan
  48     palette[n++] = "\x1b[38;2;255;135;255m" # pink
  49     palette[n++] = "\x1b[38;2;0;135;95m" # green
  50     palette[n++] = "\x1b[38;2;204;0;0m" # red
  51     palette[n++] = "\x1b[38;2;168;168;168m" # gray
  52     palcount = length(palette)
  53     n = 0
  54 }
  55 
  56 {
  57     # ignore cursor-movers and style-changers
  58     # gsub(/\x1b\[[0-9;]*[A-Za-z]/, "")
  59 
  60     rest = $0
  61 
  62     while (match(rest, /\.[A-Za-z][A-Za-z0-9_-]*/)) {
  63         printf "%s", substr(rest, 1, RSTART - 1)
  64 
  65         ext = substr(rest, RSTART, RLENGTH)
  66         rest = substr(rest, RSTART + RLENGTH)
  67 
  68         style = ext2style[ext]
  69         if (style == "") {
  70             style = palette[n % palcount]
  71             ext2style[ext] = style
  72             n++
  73         }
  74 
  75         printf "%s%s\x1b[0m", style, ext
  76     }
  77 
  78     print rest; fflush()
  79 }
  80 ' "$@"