#!/bin/sh

# The MIT License (MIT)
#
# Copyright © 2020-2025 pacman64
#
# Permission is hereby granted, free of charge, to any person obtaining a copy
# of this software and associated documentation files (the “Software”), to deal
# in the Software without restriction, including without limitation the rights
# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
# copies of the Software, and to permit persons to whom the Software is
# furnished to do so, subject to the following conditions:
#
# The above copyright notice and this permission notice shall be included in
# all copies or substantial portions of the Software.
#
# THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
# SOFTWARE.


# cext [options...] [files...]
#
# Color/style file EXTensions makes all file-extensions stand out, using
# different ANSI-styles as it finds new ones. Since its list of styles is
# limited, these will start being reused, given enough unique extensions.
#
# The help option is `-h`, `--h`, `-help`, or `--help`.


# handle leading options
case "$1" in
    -h|--h|-help|--help)
        awk '/^# +cext /, /^$/ { gsub(/^# ?/, ""); print }' "$0"
        exit 0
    ;;
esac

awk '
BEGIN {
    palette[n++] = "\x1b[38;2;0;95;215m" # blue
    palette[n++] = "\x1b[38;2;215;95;0m" # orange
    palette[n++] = "\x1b[38;2;135;95;255m" # purple
    palette[n++] = "\x1b[38;2;0;175;215m" # cyan
    palette[n++] = "\x1b[38;2;255;135;255m" # pink
    palette[n++] = "\x1b[38;2;0;135;95m" # green
    palette[n++] = "\x1b[38;2;204;0;0m" # red
    palette[n++] = "\x1b[38;2;168;168;168m" # gray
    palcount = length(palette)
    n = 0
}

{
    # ignore cursor-movers and style-changers
    # gsub(/\x1b\[[0-9;]*[A-Za-z]/, "")

    rest = $0

    while (match(rest, /\.[A-Za-z][A-Za-z0-9_-]*/)) {
        printf "%s", substr(rest, 1, RSTART - 1)

        ext = substr(rest, RSTART, RLENGTH)
        rest = substr(rest, RSTART + RLENGTH)

        style = ext2style[ext]
        if (style == "") {
            style = palette[n % palcount]
            ext2style[ext] = style
            n++
        }

        printf "%s%s\x1b[0m", style, ext
    }

    print rest; fflush()
}' "$@"