File: dtsv.awk
   1 #!/usr/bin/awk -f
   2 
   3 # The MIT License (MIT)
   4 #
   5 # Copyright © 2020-2025 pacman64
   6 #
   7 # Permission is hereby granted, free of charge, to any person obtaining a copy
   8 # of this software and associated documentation files (the “Software”), to deal
   9 # in the Software without restriction, including without limitation the rights
  10 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  11 # copies of the Software, and to permit persons to whom the Software is
  12 # furnished to do so, subject to the following conditions:
  13 #
  14 # The above copyright notice and this permission notice shall be included in
  15 # all copies or substantial portions of the Software.
  16 #
  17 # THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  20 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  22 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  23 # SOFTWARE.
  24 
  25 
  26 # dtsv [column names...]
  27 #
  28 # Drop Tab Separated-Values, ignoring all columns given, and keeping all the
  29 # others. The column names given are matched using the first line from stdin.
  30 # Matching works by first trying exact matching, then by case-insensitive
  31 # matching, when there's no exact match, finally giving up when there's no
  32 # match either way.
  33 
  34 
  35 BEGIN {
  36     FS = "\t"
  37     for (i = 1; i < ARGC; i++) {
  38         colnames[++n] = ARGV[i]
  39         lownames[n] = tolower(ARGV[i])
  40         delete ARGV[i]
  41     }
  42 }
  43 
  44 function findcol(name, lowname, i) {
  45     for (i = 1; i <= NF; i++) if (name == $i) return i
  46     for (i = 1; i <= NF; i++) if (lowname == tolower($i)) return i
  47 
  48     if (1 <= name && name <= NF) return name + 0
  49     if (name < 0 && -name <= NF) return NF + name + 1
  50 
  51     return 0
  52 }
  53 
  54 { gsub(/\r$/, "") }
  55 
  56 NR == 1 {
  57     numcols = NF
  58     for (i = 1; i <= numcols; i++) keep[i] = 1
  59 
  60     colsused = numcols
  61     for (i = 1; i <= numcols; i++) {
  62         j = findcol(colnames[i], lownames[i])
  63         if (j > 0) {
  64             keep[j] = 0
  65             colsused--
  66         }
  67     }
  68 
  69     if (colsused == 0) exit
  70 }
  71 
  72 {
  73     c = 0
  74     for (i = 1; i <= numcols; i++) {
  75         if (keep[i] == 1) {
  76             if (c > 0) printf "\t"
  77             printf "%s", $i
  78             c++
  79         }
  80     }
  81 
  82     printf "\n"; fflush()
  83 }