File: dtsv.sh
   1 #!/bin/sh
   2 
   3 # The MIT License (MIT)
   4 #
   5 # Copyright © 2020-2025 pacman64
   6 #
   7 # Permission is hereby granted, free of charge, to any person obtaining a copy
   8 # of this software and associated documentation files (the “Software”), to deal
   9 # in the Software without restriction, including without limitation the rights
  10 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  11 # copies of the Software, and to permit persons to whom the Software is
  12 # furnished to do so, subject to the following conditions:
  13 #
  14 # The above copyright notice and this permission notice shall be included in
  15 # all copies or substantial portions of the Software.
  16 #
  17 # THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  20 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  22 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  23 # SOFTWARE.
  24 
  25 
  26 # dtsv [column names...]
  27 #
  28 # Drop Tab Separated-Values, ignoring all columns given, and keeping all the
  29 # others. The column names given are matched using the first line from stdin.
  30 # Matching works by first trying exact matching, then by case-insensitive
  31 # matching, when there's no exact match, finally giving up when there's no
  32 # match either way.
  33 
  34 
  35 
  36 # case "$1" in
  37 #     -h|--h|-help|--help)
  38 #         awk '/^# +dtsv /, /^$/ { gsub(/^# ?/, ""); print }' "$0"
  39 #         exit 0
  40 #     ;;
  41 # esac
  42 
  43 awk -F "\t" '
  44     BEGIN {
  45         for (i = 1; i < ARGC; i++) {
  46             colnames[++n] = ARGV[i]
  47             lownames[n] = tolower(ARGV[i])
  48             delete ARGV[i]
  49         }
  50     }
  51 
  52     function findcol(name, lowname, i) {
  53         for (i = 1; i <= NF; i++) if (name == $i) return i
  54         for (i = 1; i <= NF; i++) if (lowname == tolower($i)) return i
  55 
  56         if (1 <= name && name <= NF) return name + 0
  57         if (name < 0 && -name <= NF) return NF + name + 1
  58 
  59         return 0
  60     }
  61 
  62     { gsub(/\r$/, "") }
  63 
  64     NR == 1 {
  65         numcols = NF
  66         for (i = 1; i <= numcols; i++) keep[i] = 1
  67 
  68         colsused = numcols
  69         for (i = 1; i <= numcols; i++) {
  70             j = findcol(colnames[i], lownames[i])
  71             if (j > 0) {
  72                 keep[j] = 0
  73                 colsused--
  74             }
  75 
  76             if (j == 0) {
  77                 fmt = "\x1b[31mno column match for \"%s\"\x1b[0m\n"
  78                 printf(fmt, colnames[i]) > "/dev/stderr"
  79                 errors++
  80             }
  81         }
  82 
  83         if (errors > 0) exit 1
  84         if (colsused == 0) exit
  85     }
  86 
  87     {
  88         c = 0
  89         for (i = 1; i <= numcols; i++) {
  90             if (keep[i] == 1) {
  91                 if (c > 0) printf "\t"
  92                 printf "%s", $i
  93                 c++
  94             }
  95         }
  96 
  97         printf "\n"; fflush()
  98     }
  99 ' "$@"