File: dtsv.sh
   1 #!/bin/sh
   2 
   3 # The MIT License (MIT)
   4 #
   5 # Copyright © 2024 pacman64
   6 #
   7 # Permission is hereby granted, free of charge, to any person obtaining a copy
   8 # of this software and associated documentation files (the “Software”), to deal
   9 # in the Software without restriction, including without limitation the rights
  10 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  11 # copies of the Software, and to permit persons to whom the Software is
  12 # furnished to do so, subject to the following conditions:
  13 #
  14 # The above copyright notice and this permission notice shall be included in
  15 # all copies or substantial portions of the Software.
  16 #
  17 # THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  20 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  22 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  23 # SOFTWARE.
  24 
  25 
  26 # dtsv [column names...]
  27 #
  28 # Drop Tab Separated-Values, ignoring all columns given, and keeping all the
  29 # others. The column names given are matched using the first line from stdin.
  30 # Matching works by first trying exact matching, then by case-insensitive
  31 # matching, when there's no exact match, finally giving up when there's no
  32 # match either way.
  33 
  34 
  35 # handle leading options
  36 case "$1" in
  37     -h|--h|-help|--help)
  38         awk '/^# +dtsv/, /^$/ { gsub(/^# ?/, ""); print }' "$0"
  39         exit 0
  40     ;;
  41 esac
  42 
  43 
  44 awk -F "\t" '
  45 BEGIN {
  46     for (i = 1; i < ARGC; i++) {
  47         colnames[++n] = ARGV[i]
  48         delete ARGV[i]
  49     }
  50 }
  51 
  52 function findcol(name, lowname, i) {
  53     for (i = 1; i <= NF; i++) {
  54         if (name == $i) return i
  55     }
  56 
  57     for (i = 1; i <= NF; i++) {
  58         if (lowname == tolower($i)) return i
  59     }
  60 
  61     if (1 <= name && name <= NF) return name + 0
  62     if (name < 0 && -name <= NF) return NF + name + 1
  63 
  64     return 0
  65 }
  66 
  67 NR == 1 {
  68     numcols = NF
  69     for (i = 1; i <= numcols; i++) keep[i] = 1
  70     for (i = 1; i <= n; i++) lownames[i] = tolower(colnames[i])
  71 
  72     colsused = numcols
  73     for (i = 1; i <= numcols; i++) {
  74         j = findcol(colnames[i], lownames[i])
  75         if (j > 0) {
  76             keep[j] = 0
  77             colsused--
  78         }
  79     }
  80 
  81     if (colsused == 0) exit
  82 }
  83 
  84 {
  85     c = 0
  86     for (i = 1; i <= numcols; i++) {
  87         if (keep[i] == 1) {
  88             if (c > 0) printf "\t"
  89             printf "%s", $i
  90             c++
  91         }
  92     }
  93 
  94     printf "\n"
  95     fflush()
  96 }
  97 ' "$@"