File: jsons.sh
   1 #!/bin/sh
   2 
   3 # The MIT License (MIT)
   4 #
   5 # Copyright © 2020-2025 pacman64
   6 #
   7 # Permission is hereby granted, free of charge, to any person obtaining a copy
   8 # of this software and associated documentation files (the “Software”), to deal
   9 # in the Software without restriction, including without limitation the rights
  10 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  11 # copies of the Software, and to permit persons to whom the Software is
  12 # furnished to do so, subject to the following conditions:
  13 #
  14 # The above copyright notice and this permission notice shall be included in
  15 # all copies or substantial portions of the Software.
  16 #
  17 # THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  20 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  22 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  23 # SOFTWARE.
  24 
  25 
  26 # jsons [options...] [filenames...]
  27 #
  28 # JSON Strings turns TSV (tab-separated values) data into a JSON array of
  29 # objects whose values are strings or nulls, the latter being used for
  30 # missing trailing values.
  31 
  32 
  33 case "$1" in
  34     -h|--h|-help|--help)
  35         awk '/^# +jsons /, /^$/ { gsub(/^# ?/, ""); print }' "$0"
  36         exit 0
  37     ;;
  38 esac
  39 
  40 if [ $# -gt 1 ]; then
  41     printf "\e[31mmultiple inputs not allowed\e[0m\n" > /dev/stderr
  42     exit 1
  43 fi
  44 
  45 
  46 awk -F "\t" '
  47     function stringify(s) {
  48         gsub(/\\/, "\\\\", s)
  49         gsub(/"/, "\\\"", s)
  50         return sprintf("\"%s\"", s)
  51     }
  52 
  53     { gsub(/\r$/, "") }
  54 
  55     NR == 1 {
  56         key_count = NF
  57         for (i = 1; i <= NF; i++) {
  58             keys[i] = stringify($i)
  59         }
  60         next
  61     }
  62 
  63     NR == 2 { printf "[\n"; fflush() }
  64     NR > 2 { printf ",\n"; fflush() }
  65 
  66     {
  67         if (NF > key_count) {
  68             msg = "found row with more values than the keys/header"
  69             printf "\x1b[31m%s\x1b[0m\n", msg > "/dev/stderr"
  70             exit 1
  71         }
  72 
  73         printf "  {"
  74         for (i = 1; i <= NF; i++) {
  75             if (i > 1) printf ", "
  76             printf "%s: %s", keys[i], stringify($i)
  77         }
  78         for (i = NF + 1; i <= key_count; i++) {
  79             printf ", %s: null", keys[i]
  80         }
  81         printf "}"; fflush()
  82     }
  83 
  84     END {
  85         printf (NR <= 1) ? "[]\n" : "\n]\n"
  86     }
  87 ' "$@"