File: jsons.sh
   1 #!/bin/sh
   2 
   3 # The MIT License (MIT)
   4 #
   5 # Copyright © 2024 pacman64
   6 #
   7 # Permission is hereby granted, free of charge, to any person obtaining a copy
   8 # of this software and associated documentation files (the “Software”), to deal
   9 # in the Software without restriction, including without limitation the rights
  10 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  11 # copies of the Software, and to permit persons to whom the Software is
  12 # furnished to do so, subject to the following conditions:
  13 #
  14 # The above copyright notice and this permission notice shall be included in
  15 # all copies or substantial portions of the Software.
  16 #
  17 # THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  20 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  22 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  23 # SOFTWARE.
  24 
  25 
  26 # jsons [options...] [filenames...]
  27 #
  28 # JSON Strings turns TSV (tab-separated values) data into a JSON array of
  29 # objects whose values are strings or nulls, the latter being used for
  30 # missing trailing values.
  31 
  32 
  33 # handle leading options
  34 case "$1" in
  35     -h|--h|-help|--help)
  36         awk '/^# +jsons/, /^$/ { gsub(/^# ?/, ""); print }' "$0"
  37         exit 0
  38     ;;
  39 esac
  40 
  41 if [ $# -gt 1 ]; then
  42     printf "\e[31mmultiple inputs not allowed\e[0m\n" > /dev/stderr
  43     exit 1
  44 fi
  45 
  46 
  47 awk -F "\t" '
  48 function stringify(s) {
  49     # gsub(/[\\"]/, "\\\1", s)
  50     gsub(/\\/, "\\\\", s)
  51     gsub(/"/, "\\\"", s)
  52     return sprintf("\"%s\"", s)
  53 }
  54 
  55 { gsub(/\r$/, "") }
  56 
  57 NR == 1 {
  58     key_count = NF
  59     for (i = 1; i <= NF; i++) {
  60         keys[i] = stringify($i)
  61     }
  62     printf "["
  63     next
  64 }
  65 
  66 NR == 2 { printf "\n" }
  67 NR > 2 { printf ",\n" }
  68 
  69 {
  70     if (NF > key_count) {
  71         msg = "found row with more values than the keys/header"
  72         printf "\x1b[31m%s\x1b[0m\n", msg > "/dev/stderr"
  73         exit 1
  74     }
  75 
  76     printf "  {"
  77     for (i = 1; i <= NF; i++) {
  78         if (i > 1) printf ", "
  79         printf "%s: %s", keys[i], stringify($i)
  80     }
  81     for (i = NF + 1; i <= key_count; i++) {
  82         printf ", %s: null", keys[i]
  83     }
  84     printf "}"
  85     fflush()
  86 }
  87 
  88 END {
  89     if (NR > 1) printf "\n"
  90     printf "]\n"
  91 }' "$@"