File: ptsv.awk
   1 #!/usr/bin/awk -f
   2 
   3 # The MIT License (MIT)
   4 #
   5 # Copyright © 2020-2025 pacman64
   6 #
   7 # Permission is hereby granted, free of charge, to any person obtaining a copy
   8 # of this software and associated documentation files (the “Software”), to deal
   9 # in the Software without restriction, including without limitation the rights
  10 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  11 # copies of the Software, and to permit persons to whom the Software is
  12 # furnished to do so, subject to the following conditions:
  13 #
  14 # The above copyright notice and this permission notice shall be included in
  15 # all copies or substantial portions of the Software.
  16 #
  17 # THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  20 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  22 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  23 # SOFTWARE.
  24 
  25 
  26 # ptsv [column names...]
  27 #
  28 # Pick Tab Separated-Values, trying to match the column names given using the
  29 # first line from stdin. Matching works by first trying exact matching, then
  30 # case-insensitive matching, when there's no exact match, finally giving up
  31 # when there's no match either way.
  32 
  33 
  34 BEGIN {
  35     FS = "\t"
  36     for (i = 1; i < ARGC; i++) {
  37         colnames[++n] = ARGV[i]
  38         lownames[n] = tolower(ARGV[i])
  39         delete ARGV[i]
  40     }
  41 }
  42 
  43 function findcol(name, lowname, i) {
  44     for (i = 1; i <= NF; i++) if (name == $i) return i
  45     for (i = 1; i <= NF; i++) if (lowname == tolower($i)) return i
  46 
  47     if (1 <= name && name <= NF) return name + 0
  48     if (name < 0 && -name <= NF) return NF + name + 1
  49 
  50     return 0
  51 }
  52 
  53 { gsub(/\r$/, "") }
  54 
  55 NR == 1 {
  56     for (i = 1; i <= NF; i++) {
  57         j = findcol(colnames[i], lownames[i])
  58         if (j > 0) pick[++numcols] = j
  59     }
  60 
  61     if (numcols == 0) exit
  62 }
  63 
  64 {
  65     for (i = 1; i <= numcols; i++) {
  66         if (i > 1) printf "\t"
  67         printf "%s", $(pick[i])
  68     }
  69 
  70     printf "\n"; fflush()
  71 }