File: ptsv.sh
   1 #!/bin/sh
   2 
   3 # The MIT License (MIT)
   4 #
   5 # Copyright © 2020-2025 pacman64
   6 #
   7 # Permission is hereby granted, free of charge, to any person obtaining a copy
   8 # of this software and associated documentation files (the “Software”), to deal
   9 # in the Software without restriction, including without limitation the rights
  10 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  11 # copies of the Software, and to permit persons to whom the Software is
  12 # furnished to do so, subject to the following conditions:
  13 #
  14 # The above copyright notice and this permission notice shall be included in
  15 # all copies or substantial portions of the Software.
  16 #
  17 # THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  20 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  22 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  23 # SOFTWARE.
  24 
  25 
  26 # ptsv [column names...]
  27 #
  28 # Pick Tab Separated-Values, trying to match the column names given using the
  29 # first line from stdin. Matching works by first trying exact matching, then
  30 # case-insensitive matching, when there's no exact match, finally giving up
  31 # when there's no match either way.
  32 
  33 
  34 case "$1" in
  35     -h|--h|-help|--help)
  36         awk '/^# +ptsv /, /^$/ { gsub(/^# ?/, ""); print }' "$0"
  37         exit 0
  38     ;;
  39 esac
  40 
  41 [ "$1" = "--" ] && shift
  42 
  43 command="awk"
  44 if [ -p 1 ] || [ -t 1 ]; then
  45     command="stdbuf -oL awk"
  46 fi
  47 
  48 ${command} -F "\t" '
  49     BEGIN {
  50         for (i = 1; i < ARGC; i++) {
  51             colnames[++n] = ARGV[i]
  52             lownames[n] = tolower(ARGV[i])
  53             delete ARGV[i]
  54         }
  55     }
  56 
  57     function findcol(name, lowname, i) {
  58         for (i = 1; i <= NF; i++) if (name == $i) return i
  59         for (i = 1; i <= NF; i++) if (lowname == tolower($i)) return i
  60 
  61         if (1 <= name && name <= NF) return name + 0
  62         if (name < 0 && -name <= NF) return NF + name + 1
  63 
  64         return 0
  65     }
  66 
  67     { gsub(/\r$/, "") }
  68 
  69     NR == 1 {
  70         for (i = 1; i <= n; i++) {
  71             j = findcol(colnames[i], lownames[i])
  72             if (j > 0) pick[++numcols] = j
  73 
  74             if (j == 0) {
  75                 fmt = "\x1b[31mno column match for \"%s\"\x1b[0m\n"
  76                 printf(fmt, colnames[i]) > "/dev/stderr"
  77                 errors++
  78             }
  79         }
  80 
  81         if (errors > 0) exit 1
  82         if (numcols == 0) exit
  83     }
  84 
  85     {
  86         for (i = 1; i <= numcols; i++) {
  87             if (i > 1) printf "\t"
  88             printf "%s", $(pick[i])
  89         }
  90 
  91         printf "\n"
  92     }
  93 ' "$@"