File: rtsv.sh
   1 #!/bin/sh
   2 
   3 # The MIT License (MIT)
   4 #
   5 # Copyright © 2020-2025 pacman64
   6 #
   7 # Permission is hereby granted, free of charge, to any person obtaining a copy
   8 # of this software and associated documentation files (the “Software”), to deal
   9 # in the Software without restriction, including without limitation the rights
  10 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  11 # copies of the Software, and to permit persons to whom the Software is
  12 # furnished to do so, subject to the following conditions:
  13 #
  14 # The above copyright notice and this permission notice shall be included in
  15 # all copies or substantial portions of the Software.
  16 #
  17 # THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  20 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  22 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  23 # SOFTWARE.
  24 
  25 
  26 # rtsv [options...] [filenames...]
  27 #
  28 # Realign Tab Separated-Values, by padding with spaces to match each column's
  29 # widest value, right-aligning all numbers.
  30 
  31 
  32 case "$1" in
  33     -h|--h|-help|--help)
  34         awk '/^# +rtsv /, /^$/ { gsub(/^# ?/, ""); print }' "$0"
  35         exit 0
  36     ;;
  37 esac
  38 
  39 [ "$1" = "--" ] && shift
  40 
  41 command="awk"
  42 if [ -p 1 ] || [ -t 1 ]; then
  43     command="stdbuf -oL awk"
  44 fi
  45 
  46 ${command} -F "\t" '
  47     function match_number(v) {
  48         return match(v, /^[+-]?[0-9]+(\.[0-9]+)?$/)
  49     }
  50 
  51     function match_dot_digits(v) {
  52         return match(v, /\.[0-9]+$/)
  53     }
  54 
  55     {
  56         gsub(/\r$/, "")
  57 
  58         for (i = 1; i <= NF; i++) {
  59             data[NR][i] = $i
  60 
  61             if (match_number($i)) {
  62                 if (match_dot_digits($i)) {
  63                     dd = RLENGTH
  64                     if (dot_decs[i] < dd) dot_decs[i] = dd
  65                     iw = RSTART - 1
  66                     if (int_widths[i] < iw) int_widths[i] = iw
  67                 } else {
  68                     w = length($i)
  69                     if (int_widths[i] < w) int_widths[i] = w
  70                 }
  71 
  72                 continue
  73             }
  74 
  75             w = length($i)
  76             if (widths[i] < w) widths[i] = w
  77         }
  78     }
  79 
  80     END {
  81         # fix column-widths using the number-padding info
  82         for (i = 1; i <= NF; i++) {
  83             w = int_widths[i] + dot_decs[i]
  84             if (widths[i] < w) widths[i] = w
  85         }
  86 
  87         for (i = 1; i <= NR; i++) {
  88             last = length(data[i])
  89 
  90             for (j = 1; j <= last; j++) {
  91                 if (j > 1) printf "  " # put 2-space gaps between columns
  92 
  93                 v = data[i][j]
  94 
  95                 if (!match_number(v)) {
  96                     # avoid adding trailing spaces at the end of lines
  97                     printf "%*s", (j == last) ? 0 : -widths[j], v
  98                     continue
  99                 }
 100 
 101                 w = length(v)
 102                 if (match_dot_digits(v)) {
 103                     dd = RLENGTH
 104                     iw = RSTART - 1
 105                 } else {
 106                     dd = 0
 107                     iw = w
 108                 }
 109 
 110                 dpad = dot_decs[j] - dd
 111                 ipad = int_widths[j] - iw
 112                 if (ipad < 0) ipad = 0
 113                 lpad = widths[j] - (ipad + w + dpad)
 114                 if (lpad < 0) lpad = 0
 115 
 116                 # avoid adding trailing spaces at the end of lines
 117                 if (j == last) dpad = 0
 118 
 119                 printf "%*s%*s%s%*s", lpad, "", ipad, "", v, dpad, ""
 120             }
 121 
 122             printf "\n"
 123         }
 124     }
 125 ' "$@"