File: sbs.sh
   1 #!/bin/sh
   2 
   3 # The MIT License (MIT)
   4 #
   5 # Copyright (c) 2026 pacman64
   6 #
   7 # Permission is hereby granted, free of charge, to any person obtaining a copy
   8 # of this software and associated documentation files (the "Software"), to deal
   9 # in the Software without restriction, including without limitation the rights
  10 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  11 # copies of the Software, and to permit persons to whom the Software is
  12 # furnished to do so, subject to the following conditions:
  13 #
  14 # The above copyright notice and this permission notice shall be included in
  15 # all copies or substantial portions of the Software.
  16 #
  17 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  20 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  22 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  23 # SOFTWARE.
  24 
  25 
  26 # sbs [column count...] [files...]
  27 #
  28 # Side-By-Side lays out lines read from all inputs given into several columns,
  29 # separating them with a special symbol. If no named inputs are given, lines
  30 # are read from the standard input, instead of files.
  31 #
  32 # If a column-count isn't given, the script tries to find the most columns
  33 # which can fit a reasonable width-limit; when even a single column can't fit
  34 # that limit, it simply emits all lines, which is the same as using 1 column.
  35 
  36 
  37 case "$1" in
  38     -h|--h|-help|--help)
  39         awk '/^# +sbs /, /^$/ { gsub(/^# ?/, ""); print }' "$0"
  40         exit 0
  41     ;;
  42 esac
  43 
  44 num_columns=0
  45 if echo "$1" | grep -q -E '^[+-]?[0-9]+$'; then
  46     num_columns="$1"
  47     shift
  48 fi
  49 
  50 fancy_sep=1
  51 case "$1" in
  52     -no-sep|--no-sep|-s|--s|-simple|--simple)
  53         fancy_sep=0
  54         shift
  55     ;;
  56 esac
  57 
  58 [ "$1" = '--' ] && shift
  59 
  60 # show all non-existing files given
  61 failed=0
  62 for arg in "$@"; do
  63     if [ "${arg}" = "-" ]; then
  64         continue
  65     fi
  66     if [ ! -e "${arg}" ]; then
  67         printf "no file named \"%s\"\n" "${arg}" >&2
  68         failed=1
  69     fi
  70 done
  71 
  72 # in case of errors, avoid showing an empty screen
  73 if [ "${failed}" -gt 0 ]; then
  74     exit 2
  75 fi
  76 
  77 # allow loading lines from multiple files, ensuring no lines are accidentally
  78 # joined across inputs
  79 awk 1 "$@" |
  80 
  81 # ignore leading UTF-8 BOMs (byte-order marks) and trailing carriage-returns:
  82 # the latter in particular will ruin side-by-side output; doing it separately
  83 # using `sed` is faster overall for the script
  84 sed 's-^\xef\xbb\xbf--; s-\r$--' |
  85 
  86 # before laying out lines side-by-side, expand all tabs, using 4 as the
  87 # tabstop width
  88 expand -t 4 |
  89 
  90 # lay lines into side-by-side columns
  91 awk -v fancy="${fancy_sep}" -v num_columns="${num_columns}" '
  92     BEGIN {
  93         sep = fancy ? " █" : " "
  94         sep_width = width(sep)
  95         total_max_width = 79
  96         max_auto_cols = 26
  97 
  98         # num_columns = 0
  99         # detect a leading number, and use it as the max-number of columns
 100         if (ARGV[1] + 0 != 0) {
 101             num_columns = ARGV[1] + 0
 102             delete ARGV[1]
 103         }
 104     }
 105 
 106     # remember all lines; carriage-returns are already removed
 107     { lines[NR] = $0 }
 108 
 109     # width counts items in the string given, ignoring ANSI-style sequences
 110     function width(s) {
 111         gsub(/\x1b\[[0-9;]*[A-Za-z]/, "", s)
 112         return length(s)
 113     }
 114 
 115     # pick a line using a row-column pair as an index
 116     function pick(lines, height, row, col) {
 117         return lines[(col - 1) * height + row]
 118     }
 119 
 120     function ceiling(n) { return (n % 1) ? n - (n % 1) + 1 : n }
 121 
 122     # see if a list of lines can fit the number of columns given exactly
 123     function fits(lines, num_lines, num_cols, height, max_widths, i, j, w, l) {
 124         height = ceiling(num_lines / num_cols)
 125 
 126         # prevent too many empty columns
 127         if (height * num_cols - num_lines >= height) return 0
 128 
 129         for (i = 1; i <= height; i++) {
 130             for (j = 1; j <= num_cols; j++) {
 131                 w = width(pick(lines, height, i, j))
 132                 if (w > total_max_width) return 0
 133                 if (max_widths[j] < w) max_widths[j] = w
 134             }
 135         }
 136 
 137         for (i = 1; i <= height; i++) {
 138             w = 0
 139 
 140             for (j = 1; j <= num_cols; j++) {
 141                 if (j > 1) w += sep_width
 142 
 143                 l = pick(lines, height, i, j)
 144                 if (j > 1 && l != "") w++
 145 
 146                 w += width(l)
 147 
 148                 if (j < num_cols) {
 149                     pad = max_widths[j] - width(l)
 150                     if (pad > 0) {
 151                         if (l == "") pad++
 152                         w += pad
 153                     }
 154                 }
 155 
 156                 if (w > total_max_width) return 0
 157             }
 158         }
 159 
 160         return 1
 161     }
 162 
 163     # auto-detect an appropriate column-count for the list of lines given
 164     function find_max_fit(lines, num_columns) {
 165         if (!fits(lines, NR, 1)) return 1
 166 
 167         for (num_columns = max_auto_cols; num_columns >= 2; num_columns--) {
 168             if (fits(lines, NR, num_columns)) return num_columns
 169         }
 170         return 1
 171     }
 172 
 173     END {
 174         # prevent errors when input has no lines
 175         if (NR < 1) exit
 176 
 177         # auto-fit when given a non-positive count, or when not given a count
 178         if (num_columns < 1) num_columns = find_max_fit(lines)
 179 
 180         # prevent column-count from exceeding the number of input lines
 181         if (num_columns > NR) num_columns = NR
 182 
 183         # emit a single column as lines, quitting right away
 184         if (num_columns < 2) {
 185             for (i = 1; i <= NR; i++) print lines[i]
 186             exit
 187         }
 188 
 189         # prevent a trailing empty column
 190         num_lines = ceiling(NR / num_columns)
 191         if (num_lines * num_columns - NR >= num_lines) num_columns--
 192 
 193         num_lines = ceiling(NR / num_columns)
 194         for (i = 1; i <= num_lines; i++) {
 195             for (j = 1; j <= num_columns; j++) {
 196                 w = width(pick(lines, num_lines, i, j))
 197                 if (max_widths[j] < w) max_widths[j] = w
 198             }
 199         }
 200 
 201         widest = 0
 202         for (i = 1; i <= num_columns; i++) {
 203             if (widest < max_widths[i]) widest = max_widths[i]
 204         }
 205 
 206         # emit lines side by side
 207         for (i = 1; i <= num_lines; i++) {
 208             for (j = 1; j <= num_columns; j++) {
 209                 l = pick(lines, num_lines, i, j)
 210 
 211                 if (j > 1) {
 212                     printf "%s", sep
 213                     if (j != num_columns || l != "") printf " "
 214                 }
 215 
 216                 printf "%s", l
 217 
 218                 if (j < num_columns) {
 219                     pad = max_widths[j] - width(l)
 220                     # if (pad > 0) printf "%*s", pad, ""
 221                     for (k = 1; k <= pad; k++) printf " "
 222                 }
 223             }
 224 
 225             print ""
 226         }
 227     }
 228 ' |
 229 
 230 # view the result interactively, if possible
 231 { less -MKiCRS 2> /dev/null || less -RIMS 2> /dev/null || cat; }